ohmyzsh/plugins/vagrant/_vagrant

#compdef vagrant 
#autoload

# vagrant zsh completion

local -a _1st_arguments
_1st_arguments=(
    'box:Box commands'
    'connect:Connects to a shared, remote Vagrant environment'
    'destroy:Destroys the vagrant environment'
    'docker-logs:Shows Docker logs'
    'docker-run:Run one-off commands against a Docker container'
    'global-status:Reports the status of all active Vagrant environments on the system'
    'halt:Halts the currently running vagrant environment'
    'init:[box_name] [box_url] Initializes current folder for Vagrant usage'
    'login:Authenticates against a Vagrant Cloud server to access protected boxes'
    'package:Packages a vagrant environment for distribution'
    'plugin:Plugin commands'
    'provision:Run the provisioner'
    'reload:Reload the vagrant environment'
    'resume:Resumes a suspend vagrant environment'
    'share:Shares the Vagrant environment and allows remote access'
    'ssh:SSH into the currently running environment'
    'ssh-config:outputs .ssh/config valid syntax for connecting to this environment via ssh'
    'status:Shows the status of the current Vagrant environment'
    'suspend:Suspends the currently running vagrant environment'
    'up:Creates the vagrant environment'
    'version:Prints the currently installed Vagrant version and checks for new updates'
    '--help:[TASK] Describe available tasks or one specific task'
    '--version:Prints the Vagrant version information'
)

local -a _box_arguments
_box_arguments=(
    'add:NAME URI Add a box to the system'
    'help:COMMAND Describe subcommands or one specific subcommand'
    'list:Lists all installed boxes'
    'remove:NAME Remove a box from the system'
    'repackage:NAME Repackage an installed box into a `.box` file.'
)

__task_list ()
{
    local expl
    declare -a tasks

    tasks=(box destroy halt init package provision reload resume ssh \
           ssh_config status suspend up version)

    _wanted tasks expl 'help' compadd $tasks
}

__box_list ()
{
    _wanted application expl 'command' compadd $(command vagrant box list | \
                                                 awk '{print $1}' | \
                                                 sed -e 's/ /\\ /g')
}

_vagrant_caching_policy()
{
    local reg_time comp_time check_file

    case "${1##*/}" in
        VAGRANT_VMS)
            if [[ -z $VAGRANT_CWD ]]; then
                check_file=./Vagrantfile
            else
                check_file=$VAGRANT_CWD/Vagrantfile
            fi
            ;;
        *)
            echo "unknown type: $1"
            return -1
            ;;
    esac

    case $(uname -s) in
        Darwin) STATCMD="stat -f '%c'" ;;
        *)      STATCMD="stat -c '%Z'" ;;
    esac
    reg_time=${$(${(z)STATCMD} $check_file):Q}
    comp_time=${$(${(z)STATCMD} $1):Q}

    return $(( reg_time < comp_time ))
 }

__vm_list ()
{
    local cache_policy
    zstyle -s ":completion:${curcontext}:" cache-policy cache_policy
    zstyle ":completion:${curcontext}:" cache-policy \
        ${cache_policy:-_vagrant_caching_policy}

    # Cache the list of VMs available
    if ( [[ ${+_vagrant_vms} -eq 0 ]] || _cache_invalid VAGRANT_VMS ) &&
        ! _retrieve_cache VAGRANT_VMS;
    then
      _vagrant_vms=( $(_call_program path-all "vagrant status | \
                       awk '{print \$1}' | \
                       egrep -v '^$|^(Current|This|above|VM,)$'" ) )
      _store_cache VAGRANT_VMS _vagrant_vms
    fi

    _wanted application expl 'command' compadd $_vagrant_vms
}

__vagrant-box ()
{
    local curcontext="$curcontext" state line
    typeset -A opt_args

    _arguments -C \
        ':command:->command' \
        '*::options:->options'

   case $state in
       (command)
           _describe -t commands "gem subcommand" _box_arguments
           return
       ;;

       (options)
           case $line[1] in
               (repackage|remove)
                   _arguments ':feature:__box_list' 
               ;;
           esac
       ;;
    esac
}




local expl
local -a boxes installed_boxes

local curcontext="$curcontext" state line
typeset -A opt_args

_arguments -C \
    ':command:->command' \
    '*::options:->options'

case $state in
  (command)
      _describe -t commands "gem subcommand" _1st_arguments
      return
  ;;

  (options)
    case $line[1] in
      (help)
         _arguments ':feature:__task_list' 
      ;;

      (box)
          __vagrant-box
      ;;
      (up|provision|package|destroy|reload|ssh|halt|resume|status|suspend)
          _arguments ':feature:__vm_list'
    esac
  ;;
esac