ohmyzsh/plugins/battery/battery.plugin.zsh

###########################################
# Battery plugin for oh-my-zsh            #
# Original Author: Peter hoeg (peterhoeg) #
# Email: peter@speartail.com              #
###########################################
# Author: Sean Jones (neuralsandwich)     #
# Email: neuralsandwich@gmail.com         #
# Modified to add support for Apple Mac   #
###########################################

if [[ $(uname) == "Darwin" ]] ; then

  function battery_pct() {
    typeset -F maxcapacity=$(ioreg -rc "AppleSmartBattery"| grep '^.*"MaxCapacity"\ =\ ' | sed -e 's/^.*"MaxCapacity"\ =\ //')
    typeset -F currentcapacity=$(ioreg -rc "AppleSmartBattery"| grep '^.*"CurrentCapacity"\ =\ ' | sed -e 's/^.*CurrentCapacity"\ =\ //')
    integer i=$(((currentcapacity/maxcapacity) * 100))
    echo $i
  }
  
  function charger_connected() {
    if [[ $(ioreg -rc AppleSmartBattery | grep -c '^.*"ExternalConnected"\ =\ No') -eq 1 ]] ; then
      echo "NO"
    else
      echo "YES"
    fi 
  }
  
  function charging_state() {
    if [[ $(charger_connected) == "YES" ]] ; then
      echo "C"
    else
      echo "D"
    fi
  }
  
  function battery_pct_remaining() {
      echo "$(battery_pct)"
    }
    
  function time_to_full {
    echo $(ioreg -rc "AppleSmartBattery"| grep '^.*"AvgTimeToFull"\ =\ ' | sed -e 's/^.*"AvgTimeToFull"\ =\ //')
  }
  function time_to_empty {
    echo $(ioreg -rc "AppleSmartBattery"| grep '^.*"TimeRemaining"\ =\ ' | sed -e 's/^.*"TimeRemaining"\ =\ //')
  }
  
  function battery_time_remaining() {
    timeremaining=$(time_to_empty)
    timetofull=$(time_to_full)
    if [[ $(charger_connected) == "NO" ]] ; then
      echo "~$((timeremaining / 60)):$((timeremaining % 60))"
    else
      echo "~$((timetofull / 60)):$((timetofull % 60))"
    fi
  }

  function battery_pct_prompt () {
    if [[ $(charger_connected) == "NO" ]] ; then
      b=$(battery_pct_remaining)
      if [ $b -gt 50 ] ; then
        color='green'
      elif [ $b -gt 20 ] ; then
        color='yellow'
      else
        color='red'
      fi
      echo "%{$fg[$color]%}[$(battery_pct_remaining)%%]%{$reset_color%}"
    else
      echo "∞"
    fi
  }


elif [[ $(uname) == "Linux"  ]] ; then

  function battery_pct_remaining() {
    if [[ $(acpi 2&>/dev/null | grep -c '^Battery.*Discharging') -gt 0 ]] ; then
      echo "$(acpi | cut -f2 -d ',' | tr -cd '[:digit:]')" 
    fi
  }

  function battery_time_remaining() {
    if [[ $(acpi 2&>/dev/null | grep -c '^Battery.*Discharging') -gt 0 ]] ; then
      echo $(acpi | cut -f3 -d ',')
    fi
  }

  function battery_pct_prompt() {
    b=$(battery_pct_remaining) 
    if [[ $(acpi 2&>/dev/null | grep -c '^Battery.*Discharging') -gt 0 ]] ; then
      if [ $b -gt 50 ] ; then
        color='green'
      elif [ $b -gt 20 ] ; then
        color='yellow'
      else
        color='red'
      fi
      echo "%{$fg[$color]%}[$(battery_pct_remaining)%%]%{$reset_color%}"
    else
      echo "∞"
    fi
  }
else
	# Empty functions so we don't cause errors in prompts
	function battery_pct_remaining() {
	}

	function battery_time_remaining() {
	}

	function battery_pct_prompt() {
	}
  function charger_connected() {
  }
  function charging_state() {
  }
  
fi