mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2026-03-27 03:14:56 +01:00
f0476cb78bThe allowed and disallowed list files now support zsh glob patterns (e.g., /path/to/projects/*) in addition to exact paths. This is useful for git worktree setups and other workflows where multiple directories share a common prefix. Comment lines and blank lines are now also supported in list files.
81 lines
2.2 KiB
Bash
81 lines
2.2 KiB
Bash
## Settings
|
|
|
|
# Filename of the dotenv file to look for
|
|
: ${ZSH_DOTENV_FILE:=.env}
|
|
|
|
# Path to the file containing allowed paths
|
|
: ${ZSH_DOTENV_ALLOWED_LIST:="${ZSH_CACHE_DIR:-$ZSH/cache}/dotenv-allowed.list"}
|
|
: ${ZSH_DOTENV_DISALLOWED_LIST:="${ZSH_CACHE_DIR:-$ZSH/cache}/dotenv-disallowed.list"}
|
|
|
|
|
|
## Functions
|
|
|
|
_dotenv_list_match() {
|
|
emulate -L zsh
|
|
local dirpath=$1 list_file=$2 line
|
|
|
|
[[ -r $list_file ]] || return 1
|
|
|
|
while IFS= read -r line || [[ -n $line ]]; do
|
|
[[ -z "$line" || "$line" == \#* ]] && continue
|
|
[[ $dirpath == ${~line} ]] && return 0
|
|
done < "$list_file"
|
|
|
|
return 1
|
|
}
|
|
|
|
source_env() {
|
|
if [[ ! -f "$ZSH_DOTENV_FILE" ]]; then
|
|
return
|
|
fi
|
|
|
|
if [[ "$ZSH_DOTENV_PROMPT" != false ]]; then
|
|
local confirmation dirpath="${PWD:A}"
|
|
|
|
# make sure there is an (dis-)allowed file
|
|
touch "$ZSH_DOTENV_ALLOWED_LIST"
|
|
touch "$ZSH_DOTENV_DISALLOWED_LIST"
|
|
|
|
# early return if disallowed
|
|
if _dotenv_list_match "$dirpath" "$ZSH_DOTENV_DISALLOWED_LIST"; then
|
|
return
|
|
fi
|
|
|
|
# check if current directory's .env file is allowed or ask for confirmation
|
|
if ! _dotenv_list_match "$dirpath" "$ZSH_DOTENV_ALLOWED_LIST"; then
|
|
# get cursor column and print new line before prompt if not at line beginning
|
|
local column
|
|
echo -ne "\e[6n" > /dev/tty
|
|
read -t 1 -s -d R column < /dev/tty
|
|
column="${column##*\[*;}"
|
|
[[ $column -eq 1 ]] || echo
|
|
|
|
# print same-line prompt and output newline character if necessary
|
|
echo -n "dotenv: found '$ZSH_DOTENV_FILE' file. Source it? ([Y]es/[n]o/[a]lways/n[e]ver) "
|
|
read -k 1 confirmation
|
|
[[ "$confirmation" = $'\n' ]] || echo
|
|
|
|
# check input
|
|
case "$confirmation" in
|
|
[nN]) return ;;
|
|
[aA]) print -r -- "${(b)dirpath}" >> "$ZSH_DOTENV_ALLOWED_LIST" ;;
|
|
[eE]) print -r -- "${(b)dirpath}" >> "$ZSH_DOTENV_DISALLOWED_LIST"; return ;;
|
|
*) ;; # interpret anything else as a yes
|
|
esac
|
|
fi
|
|
fi
|
|
|
|
# test .env syntax
|
|
zsh -fn $ZSH_DOTENV_FILE || {
|
|
echo "dotenv: error when sourcing '$ZSH_DOTENV_FILE' file" >&2
|
|
return 1
|
|
}
|
|
|
|
setopt localoptions allexport
|
|
source $ZSH_DOTENV_FILE
|
|
}
|
|
|
|
autoload -U add-zsh-hook
|
|
add-zsh-hook chpwd source_env
|
|
|
|
source_env
|