mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2026-02-20 03:02:29 +01:00
e4db8922ba
Without this fix, it is not possible to have fixed window titles in screen, zsh always makes automatic titles. This fixes #2015 and #1491 Users should now use the screen plugin to get an automatic windowtitle.
37 lines
1.3 KiB
Bash
37 lines
1.3 KiB
Bash
#usage: title short_tab_title looooooooooooooooooooooggggggg_windows_title
|
|
#http://www.faqs.org/docs/Linux-mini/Xterm-Title.html#ss3.1
|
|
#Fully support screen, iterm, and probably most modern xterm and rxvt
|
|
#Limited support for Apple Terminal (Terminal can't set window or tab separately)
|
|
function title {
|
|
if [[ "$DISABLE_AUTO_TITLE" == "true" ]] || [[ "$EMACS" == *term* ]]; then
|
|
return
|
|
fi
|
|
if [[ "$TERM" == xterm* ]] || [[ $TERM == rxvt* ]] || [[ $TERM == ansi ]] || [[ "$TERM_PROGRAM" == "iTerm.app" ]]; then
|
|
print -Pn "\e]2;$2:q\a" #set window name
|
|
print -Pn "\e]1;$1:q\a" #set icon (=tab) name (will override window name on broken terminal)
|
|
fi
|
|
}
|
|
|
|
ZSH_THEME_TERM_TAB_TITLE_IDLE="%15<..<%~%<<" #15 char left truncated PWD
|
|
ZSH_THEME_TERM_TITLE_IDLE="%n@%m: %~"
|
|
|
|
#Appears when you have the prompt
|
|
function omz_termsupport_precmd {
|
|
title $ZSH_THEME_TERM_TAB_TITLE_IDLE $ZSH_THEME_TERM_TITLE_IDLE
|
|
}
|
|
|
|
#Appears at the beginning of (and during) of command execution
|
|
function omz_termsupport_preexec {
|
|
emulate -L zsh
|
|
setopt extended_glob
|
|
|
|
# cmd name only, or if this is sudo or ssh, the next cmd
|
|
local CMD=${1[(wr)^(*=*|sudo|ssh|rake|-*)]:gs/%/%%}
|
|
local LINE="${2:gs/%/%%}"
|
|
|
|
title '$CMD' '%100>...>$LINE%<<'
|
|
}
|
|
|
|
autoload -U add-zsh-hook
|
|
add-zsh-hook precmd omz_termsupport_precmd
|
|
add-zsh-hook preexec omz_termsupport_preexec
|