mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2024-09-19 04:01:21 +02:00
bc67a55fe8
- Fixes `readlink -e` dependency which isn't supported in macOS (fixes #3235). - Uses native zsh wildcard expansion instead of calls to `ls`. - Prepends commands with `command` and `builtin` to bypass aliases and functions. - Documents CTRL+G key binding to substitute mark name in the command line with the mark path (https://github.com/ohmyzsh/ohmyzsh/pull/2045#issuecomment-22826540).
59 lines
1.4 KiB
Bash
59 lines
1.4 KiB
Bash
# Easily jump around the file system by manually adding marks
|
|
# marks are stored as symbolic links in the directory $MARKPATH (default $HOME/.marks)
|
|
#
|
|
# jump FOO: jump to a mark named FOO
|
|
# mark FOO: create a mark named FOO
|
|
# unmark FOO: delete a mark
|
|
# marks: lists all marks
|
|
#
|
|
export MARKPATH=$HOME/.marks
|
|
|
|
jump() {
|
|
builtin cd -P "$MARKPATH/$1" 2>/dev/null || {echo "No such mark: $1"; return 1}
|
|
}
|
|
|
|
mark() {
|
|
if [[ $# -eq 0 || "$1" = "." ]]; then
|
|
MARK=${PWD:t}
|
|
else
|
|
MARK="$1"
|
|
fi
|
|
if read -q "?Mark $PWD as ${MARK}? (y/n) "; then
|
|
command mkdir -p "$MARKPATH"
|
|
command ln -sfn "$PWD" "$MARKPATH/$MARK"
|
|
fi
|
|
}
|
|
|
|
unmark() {
|
|
LANG= command rm -i "$MARKPATH/$1"
|
|
}
|
|
|
|
marks() {
|
|
local max=0
|
|
for link in $MARKPATH/*(@); do
|
|
if [[ ${#link:t} -gt $max ]]; then
|
|
max=${#link:t}
|
|
fi
|
|
done
|
|
local printf_markname_template="$(printf -- "%%%us " "$max")"
|
|
for link in $MARKPATH/*(@); do
|
|
local markname="$fg[cyan]${link:t}$reset_color"
|
|
local markpath="$fg[blue]$(readlink $link)$reset_color"
|
|
printf -- "$printf_markname_template" "$markname"
|
|
printf -- "-> %s\n" "$markpath"
|
|
done
|
|
}
|
|
|
|
_completemarks() {
|
|
reply=("${MARKPATH}"/*(N:t))
|
|
}
|
|
compctl -K _completemarks jump
|
|
compctl -K _completemarks unmark
|
|
|
|
_mark_expansion() {
|
|
setopt extendedglob
|
|
autoload -U modify-current-argument
|
|
modify-current-argument '$(readlink "$MARKPATH/$ARG")'
|
|
}
|
|
zle -N _mark_expansion
|
|
bindkey "^g" _mark_expansion
|