mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2024-11-12 21:39:48 +01:00
43bd46b780
Before this patch, commands containing %-signs set the title wrong (urxvt and xterm) [1] and produce strange output in urxvt [2]. test for bug 1: > sleep 10 && echo % sets title to "sleep 10 && echo %<<" > sleep 10 && echo %f doesn't change the title at all test for bug 2 (only urxvt): > echo %f 39m%f ^^^^^----- output
35 lines
1.4 KiB
Bash
35 lines
1.4 KiB
Bash
#usage: title short_tab_title looooooooooooooooooooooggggggg_windows_title
|
|
#http://www.faqs.org/docs/Linux-mini/Xterm-Title.html#ss3.1
|
|
#Fully support screen, iterm, and probably most modern xterm and rxvt
|
|
#Limited support for Apple Terminal (Terminal can't set window or tab separately)
|
|
function title {
|
|
if [[ "$DISABLE_AUTO_TITLE" == "true" ]] || [[ "$EMACS" == *term* ]]; then
|
|
return
|
|
fi
|
|
if [[ "$TERM" == screen* ]]; then
|
|
print -Pn "\ek$1:q\e\\" #set screen hardstatus, usually truncated at 20 chars
|
|
elif [[ "$TERM" == xterm* ]] || [[ $TERM == rxvt* ]] || [[ "$TERM_PROGRAM" == "iTerm.app" ]]; then
|
|
print -Pn "\e]2;$2:q\a" #set window name
|
|
print -Pn "\e]1;$1:q\a" #set icon (=tab) name (will override window name on broken terminal)
|
|
fi
|
|
}
|
|
|
|
ZSH_THEME_TERM_TAB_TITLE_IDLE="%15<..<%~%<<" #15 char left truncated PWD
|
|
ZSH_THEME_TERM_TITLE_IDLE="%n@%m: %~"
|
|
|
|
#Appears when you have the prompt
|
|
function omz_termsupport_precmd {
|
|
title $ZSH_THEME_TERM_TAB_TITLE_IDLE $ZSH_THEME_TERM_TITLE_IDLE
|
|
}
|
|
|
|
#Appears at the beginning of (and during) of command execution
|
|
function omz_termsupport_preexec {
|
|
emulate -L zsh
|
|
setopt extended_glob
|
|
local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]} #cmd name only, or if this is sudo or ssh, the next cmd
|
|
title "$CMD" "%100>...>${2:gs/%/%%}%<<"
|
|
}
|
|
|
|
autoload -U add-zsh-hook
|
|
add-zsh-hook precmd omz_termsupport_precmd
|
|
add-zsh-hook preexec omz_termsupport_preexec
|