From 166b9dcfdc32c5ce3a2060c0c221e2df0b49fa37 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Malte=20Schl=C3=BCter?= <account@schlueter-malte.de>
Date: Tue, 11 Jun 2024 01:46:33 +0200
Subject: [PATCH] Add plugin for native autocompletion from Symfony 6 (#11999)

---
 plugins/symfony6/README.md           |  9 +++
 plugins/symfony6/symfony6.plugin.zsh | 82 ++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+)
 create mode 100644 plugins/symfony6/README.md
 create mode 100644 plugins/symfony6/symfony6.plugin.zsh

diff --git a/plugins/symfony6/README.md b/plugins/symfony6/README.md
new file mode 100644
index 000000000..54611bcee
--- /dev/null
+++ b/plugins/symfony6/README.md
@@ -0,0 +1,9 @@
+# Symfony
+
+This plugin provides native completion for [Symfony](https://symfony.com/), but requires at least Symfony 6.2.
+
+To use it add `symfony6` to the plugins array in your zshrc file.
+
+```bash
+plugins=(... symfony6)
+```
diff --git a/plugins/symfony6/symfony6.plugin.zsh b/plugins/symfony6/symfony6.plugin.zsh
new file mode 100644
index 000000000..ed7dbe60e
--- /dev/null
+++ b/plugins/symfony6/symfony6.plugin.zsh
@@ -0,0 +1,82 @@
+#compdef console
+
+# This file is part of the Symfony package.
+#
+# (c) Fabien Potencier <fabien@symfony.com>
+#
+# For the full copyright and license information, please view
+# https://symfony.com/doc/current/contributing/code/license.html
+
+#
+# zsh completions for console
+#
+# References:
+#   - https://github.com/spf13/cobra/blob/master/zsh_completions.go
+#   - https://github.com/symfony/symfony/blob/5.4/src/Symfony/Component/Console/Resources/completion.bash
+#
+_sf_console() {
+    local lastParam flagPrefix requestComp out comp
+    local -a completions
+
+    # The user could have moved the cursor backwards on the command-line.
+    # We need to trigger completion from the $CURRENT location, so we need
+    # to truncate the command-line ($words) up to the $CURRENT location.
+    # (We cannot use $CURSOR as its value does not work when a command is an alias.)
+    words=("${=words[1,CURRENT]}") lastParam=${words[-1]}
+
+    # For zsh, when completing a flag with an = (e.g., console -n=<TAB>)
+    # completions must be prefixed with the flag
+    setopt local_options BASH_REMATCH
+    if [[ "${lastParam}" =~ '-.*=' ]]; then
+        # We are dealing with a flag with an =
+        flagPrefix="-P ${BASH_REMATCH}"
+    fi
+
+    # Prepare the command to obtain completions
+    requestComp="${words[0]} ${words[1]} _complete --no-interaction -szsh -a1 -c$((CURRENT-1))" i=""
+    for w in ${words[@]}; do
+        w=$(printf -- '%b' "$w")
+        # remove quotes from typed values
+        quote="${w:0:1}"
+        if [ "$quote" = \' ]; then
+            w="${w%\'}"
+            w="${w#\'}"
+        elif [ "$quote" = \" ]; then
+            w="${w%\"}"
+            w="${w#\"}"
+        fi
+        # empty values are ignored
+        if [ ! -z "$w" ]; then
+            i="${i}-i${w} "
+        fi
+    done
+
+    # Ensure at least 1 input
+    if [ "${i}" = "" ]; then
+        requestComp="${requestComp} -i\" \""
+    else
+        requestComp="${requestComp} ${i}"
+    fi
+
+    # Use eval to handle any environment variables and such
+    out=$(eval ${requestComp} 2>/dev/null)
+
+    while IFS='\n' read -r comp; do
+        if [ -n "$comp" ]; then
+            # If requested, completions are returned with a description.
+            # The description is preceded by a TAB character.
+            # For zsh's _describe, we need to use a : instead of a TAB.
+            # We first need to escape any : as part of the completion itself.
+            comp=${comp//:/\\:}
+            local tab=$(printf '\t')
+            comp=${comp//$tab/:}
+            completions+=${comp}
+        fi
+    done < <(printf "%s\n" "${out[@]}")
+
+    # Let inbuilt _describe handle completions
+    eval _describe "completions" completions $flagPrefix
+    return $?
+}
+
+compdef _sf_console console